name({walky})
bounce(0.2)
mass(1)
graphics({
   w(70) h(80) y(0) file({images/himacs3.bmp})

   ;; Walk left (frames 0-13)
   #i(0)
   #iter([x(i 7 % 70 * 5 +) loadbmp(i) #i(i 1 +)])
   repeat(7 iter)
   y(80)
   repeat(7 iter)

   ;; Walk right (frames 14-27)
   #iter([x(i 7 % 70 * 5 +) loadflipbmp(i) #i(i 1 +)])
   repeat(7 iter)
   y(80)
   repeat(7 iter)

   ;; Stand left
   x(215) y(160)
   loadbmp(28)

   ;; Stand right
   loadflipbmp(29)
   
   ;; Falling left
   x(75)
   loadbmp(30)

   ;; Falling right
   loadflipbmp(31)

   ;; Jumping left
   x(5)
   loadbmp(32)

   ;; Jumping right
   loadflipbmp(33)
})

states({
	#i(0)
 	#iter([i 
		 {tread(8 self)}
		 #i(i 1 +)])
 	repeat(14 iter)
 	#iter([i 
		 {tread(-8 self)}
		 #i(i 1 +)])
  	repeat(14 iter)
	32 {force(0 -10 -10 self)}
	33 {force(0 10 -10 self)}
})

transitions({
	#i(0)
	#iter([i #i(i 1 +)])
	#walkleft([#i(0) repeat(14 iter)])
	#walkright([#i(14) repeat(14 iter)])

	always:
		statepath 32 30 endpath
		statepath 33 31 endpath
	contact_ground:
		statepath 30 28 endpath
		statepath 31 29 endpath
	!contact_ground:
		statesink run(walkleft) 28 30 endsink
		statesink run(walkright) 29 31 endsink
	left:
		statesink 28 29 run(walkright) 0 endsink
		statepath run(walkleft) 0 endpath	
	right:
		statesink 28 29 run(walkleft) 14 endsink
		statepath run(walkright) 14 endpath
	!left:
		statesink run(walkleft) 28 endsink
	!right:
		statesink run(walkright) 29 endsink
	up:
		statesink run(walkright) 29 33 endsink
		statesink run(walkleft) 28 32 endsink
})